Line data Source code
1 : !--------------------------------------------------------------------------------------------------!
2 : ! CP2K: A general program to perform molecular dynamics simulations !
3 : ! Copyright 2000-2026 CP2K developers group <https://cp2k.org> !
4 : ! !
5 : ! SPDX-License-Identifier: GPL-2.0-or-later !
6 : !--------------------------------------------------------------------------------------------------!
7 :
8 : MODULE qs_tddfpt2_fhxc
9 : USE admm_types, ONLY: admm_type
10 : USE cp_control_types, ONLY: dft_control_type,&
11 : stda_control_type
12 : USE cp_dbcsr_api, ONLY: &
13 : dbcsr_add, dbcsr_copy, dbcsr_create, dbcsr_deallocate_matrix, dbcsr_get_info, &
14 : dbcsr_p_type, dbcsr_release, dbcsr_set, dbcsr_type, dbcsr_type_symmetric
15 : USE cp_dbcsr_cp2k_link, ONLY: cp_dbcsr_alloc_block_from_nbl
16 : USE cp_dbcsr_operations, ONLY: copy_fm_to_dbcsr,&
17 : cp_dbcsr_plus_fm_fm_t,&
18 : cp_dbcsr_sm_fm_multiply
19 : USE cp_fm_types, ONLY: cp_fm_create,&
20 : cp_fm_get_info,&
21 : cp_fm_release,&
22 : cp_fm_type
23 : USE input_constants, ONLY: do_admm_aux_exch_func_none,&
24 : no_sf_tddfpt,&
25 : tddfpt_sf_col,&
26 : tddfpt_sf_noncol
27 : USE kinds, ONLY: default_string_length,&
28 : dp
29 : USE lri_environment_types, ONLY: lri_kind_type
30 : USE message_passing, ONLY: mp_para_env_type
31 : USE parallel_gemm_api, ONLY: parallel_gemm
32 : USE pw_env_types, ONLY: pw_env_get
33 : USE pw_methods, ONLY: pw_axpy,&
34 : pw_scale,&
35 : pw_zero
36 : USE pw_pool_types, ONLY: pw_pool_type
37 : USE pw_types, ONLY: pw_c1d_gs_type,&
38 : pw_r3d_rs_type
39 : USE qs_environment_types, ONLY: get_qs_env,&
40 : qs_environment_type
41 : USE qs_fxc, ONLY: qs_fxc_apply
42 : USE qs_gapw_densities, ONLY: prepare_gapw_den
43 : USE qs_integrate_potential, ONLY: integrate_v_rspace,&
44 : integrate_v_rspace_one_center
45 : USE qs_kernel_types, ONLY: full_kernel_env_type
46 : USE qs_ks_atom, ONLY: update_ks_atom
47 : USE qs_rho_atom_types, ONLY: rho_atom_type
48 : USE qs_rho_methods, ONLY: qs_rho_update_rho,&
49 : qs_rho_update_tddfpt
50 : USE qs_rho_types, ONLY: qs_rho_get
51 : USE qs_tddfpt2_densities, ONLY: tddfpt_construct_aux_fit_density
52 : USE qs_tddfpt2_lri_utils, ONLY: tddfpt2_lri_Amat
53 : USE qs_tddfpt2_operators, ONLY: tddfpt_apply_coulomb,&
54 : tddfpt_apply_xc_potential
55 : USE qs_tddfpt2_stda_types, ONLY: stda_env_type
56 : USE qs_tddfpt2_stda_utils, ONLY: stda_calculate_kernel
57 : USE qs_tddfpt2_subgroups, ONLY: tddfpt_subgroup_env_type
58 : USE qs_tddfpt2_types, ONLY: tddfpt_work_matrices
59 : USE task_list_types, ONLY: task_list_type
60 : #include "./base/base_uses.f90"
61 :
62 : IMPLICIT NONE
63 :
64 : PRIVATE
65 :
66 : CHARACTER(len=*), PARAMETER, PRIVATE :: moduleN = 'qs_tddfpt2_fhxc'
67 :
68 : INTEGER, PARAMETER, PRIVATE :: maxspins = 2
69 :
70 : PUBLIC :: fhxc_kernel, stda_kernel
71 :
72 : ! **************************************************************************************************
73 :
74 : CONTAINS
75 :
76 : ! **************************************************************************************************
77 : !> \brief Compute action matrix-vector products with the FHxc Kernel
78 : !> \param Aop_evects action of TDDFPT operator on trial vectors (modified on exit)
79 : !> \param evects TDDFPT trial vectors
80 : !> \param is_rks_triplets indicates that a triplet excited states calculation using
81 : !> spin-unpolarised molecular orbitals has been requested
82 : !> \param do_hfx flag that activates computation of exact-exchange terms
83 : !> \param do_admm ...
84 : !> \param qs_env Quickstep environment
85 : !> \param kernel_env kernel environment
86 : !> \param kernel_env_admm_aux kernel environment for ADMM correction
87 : !> \param sub_env parallel (sub)group environment
88 : !> \param work_matrices collection of work matrices (modified on exit)
89 : !> \param admm_symm use symmetric definition of ADMM kernel correction
90 : !> \param admm_xc_correction use ADMM XC kernel correction
91 : !> \param do_lrigpw ...
92 : !> \param tddfpt_mgrid ...
93 : !> \par History
94 : !> * 06.2016 created [Sergey Chulkov]
95 : !> * 03.2017 refactored [Sergey Chulkov]
96 : !> * 04.2019 refactored [JHU]
97 : ! **************************************************************************************************
98 4344 : SUBROUTINE fhxc_kernel(Aop_evects, evects, is_rks_triplets, &
99 : do_hfx, do_admm, qs_env, kernel_env, kernel_env_admm_aux, &
100 : sub_env, work_matrices, admm_symm, admm_xc_correction, do_lrigpw, &
101 : tddfpt_mgrid)
102 : TYPE(cp_fm_type), DIMENSION(:, :), INTENT(INOUT) :: Aop_evects
103 : TYPE(cp_fm_type), DIMENSION(:, :), INTENT(IN) :: evects
104 : LOGICAL, INTENT(in) :: is_rks_triplets, do_hfx, do_admm
105 : TYPE(qs_environment_type), POINTER :: qs_env
106 : TYPE(full_kernel_env_type), POINTER :: kernel_env, kernel_env_admm_aux
107 : TYPE(tddfpt_subgroup_env_type), INTENT(in) :: sub_env
108 : TYPE(tddfpt_work_matrices), INTENT(inout) :: work_matrices
109 : LOGICAL, INTENT(in) :: admm_symm, admm_xc_correction, &
110 : do_lrigpw, tddfpt_mgrid
111 :
112 : CHARACTER(LEN=*), PARAMETER :: routineN = 'fhxc_kernel'
113 :
114 : CHARACTER(LEN=default_string_length) :: basis_type
115 : INTEGER :: handle, ikind, ispin, ivect, nao, &
116 : nao_aux, nkind, nspins, nvects, &
117 : spinflip
118 4344 : INTEGER, DIMENSION(:), POINTER :: blk_sizes
119 : INTEGER, DIMENSION(maxspins) :: nactive
120 : LOGICAL :: do_noncol, do_onecenter, do_scale, gapw, &
121 : gapw_xc
122 : TYPE(admm_type), POINTER :: admm_env
123 : TYPE(cp_fm_type) :: work_aux_orb, work_orb_orb
124 4344 : TYPE(dbcsr_p_type), DIMENSION(:), POINTER :: A_xc_munu_sub, rho_ia_ao, &
125 4344 : rho_ia_ao_aux_fit
126 : TYPE(dbcsr_type), POINTER :: dbwork
127 : TYPE(dft_control_type), POINTER :: dft_control
128 4344 : TYPE(lri_kind_type), DIMENSION(:), POINTER :: lri_v_int
129 : TYPE(mp_para_env_type), POINTER :: para_env
130 4344 : TYPE(pw_c1d_gs_type), DIMENSION(:), POINTER :: rho_ia_g, rho_ia_g_aux_fit
131 : TYPE(pw_pool_type), POINTER :: auxbas_pw_pool
132 4344 : TYPE(pw_r3d_rs_type), DIMENSION(:), POINTER :: fxc_tau, rho_ia_r, rho_ia_r_aux_fit
133 : TYPE(pw_r3d_rs_type), POINTER :: weights
134 4344 : TYPE(rho_atom_type), DIMENSION(:), POINTER :: rho1_atom_set, rho_atom_set
135 : TYPE(task_list_type), POINTER :: task_list
136 :
137 4344 : CALL timeset(routineN, handle)
138 :
139 4344 : nspins = SIZE(evects, 1)
140 4344 : nvects = SIZE(evects, 2)
141 4344 : IF (do_admm) THEN
142 872 : CPASSERT(do_hfx)
143 872 : CPASSERT(ASSOCIATED(sub_env%admm_A))
144 : END IF
145 4344 : CALL get_qs_env(qs_env, dft_control=dft_control)
146 :
147 4344 : gapw = dft_control%qs_control%gapw
148 4344 : gapw_xc = dft_control%qs_control%gapw_xc
149 4344 : spinflip = dft_control%tddfpt2_control%spinflip
150 :
151 4344 : do_noncol = spinflip == tddfpt_sf_noncol
152 4344 : do_scale = is_rks_triplets
153 4344 : do_onecenter = gapw .OR. gapw_xc
154 :
155 4344 : CALL cp_fm_get_info(evects(1, 1), nrow_global=nao)
156 9392 : DO ispin = 1, nspins
157 9392 : CALL cp_fm_get_info(evects(ispin, 1), ncol_global=nactive(ispin))
158 : END DO
159 :
160 : CALL qs_rho_get(work_matrices%rho_orb_struct_sub, rho_ao=rho_ia_ao, &
161 4344 : rho_g=rho_ia_g, rho_r=rho_ia_r)
162 4344 : IF (do_hfx .AND. do_admm) THEN
163 872 : CALL get_qs_env(qs_env, admm_env=admm_env)
164 : CALL qs_rho_get(work_matrices%rho_aux_fit_struct_sub, &
165 : rho_ao=rho_ia_ao_aux_fit, rho_g=rho_ia_g_aux_fit, &
166 872 : rho_r=rho_ia_r_aux_fit)
167 : END IF
168 :
169 4344 : NULLIFY (weights)
170 4344 : CALL get_qs_env(qs_env, xcint_weights=weights)
171 4344 : CALL pw_env_get(sub_env%pw_env, auxbas_pw_pool=auxbas_pw_pool)
172 4344 : NULLIFY (fxc_tau)
173 :
174 13896 : DO ivect = 1, nvects
175 :
176 : ! Transform TDDFT vectors to AO space and store them into rho_ia_ao
177 9552 : IF (ALLOCATED(work_matrices%evects_sub)) THEN
178 16 : IF (ASSOCIATED(work_matrices%evects_sub(1, ivect)%matrix_struct)) THEN
179 16 : DO ispin = 1, nspins
180 8 : CALL dbcsr_set(rho_ia_ao(ispin)%matrix, 0.0_dp)
181 : CALL cp_dbcsr_plus_fm_fm_t(rho_ia_ao(ispin)%matrix, &
182 : matrix_v=sub_env%mos_active(ispin), &
183 : matrix_g=work_matrices%evects_sub(ispin, ivect), &
184 16 : ncol=nactive(ispin), symmetry_mode=1)
185 : END DO
186 : ELSE
187 : ! skip trial vectors which are assigned to different parallel groups
188 : CYCLE
189 : END IF
190 : ELSE
191 20956 : DO ispin = 1, nspins
192 11420 : CALL dbcsr_set(rho_ia_ao(ispin)%matrix, 0.0_dp)
193 : CALL cp_dbcsr_plus_fm_fm_t(rho_ia_ao(ispin)%matrix, &
194 : matrix_v=sub_env%mos_active(ispin), &
195 : matrix_g=evects(ispin, ivect), &
196 20956 : ncol=nactive(ispin), symmetry_mode=1)
197 : END DO
198 : END IF
199 :
200 9544 : IF (do_lrigpw) THEN
201 : CALL qs_rho_update_tddfpt(work_matrices%rho_orb_struct_sub, qs_env, &
202 : pw_env_external=sub_env%pw_env, &
203 : task_list_external=sub_env%task_list_orb, &
204 : para_env_external=sub_env%para_env, &
205 : tddfpt_lri_env=kernel_env%lri_env, &
206 172 : tddfpt_lri_density=kernel_env%lri_density)
207 9372 : ELSE IF (dft_control%qs_control%lrigpw .OR. &
208 : dft_control%qs_control%rigpw) THEN
209 : CALL qs_rho_update_tddfpt(work_matrices%rho_orb_struct_sub, qs_env, &
210 : pw_env_external=sub_env%pw_env, &
211 : task_list_external=sub_env%task_list_orb, &
212 0 : para_env_external=sub_env%para_env)
213 : ELSE
214 9372 : IF (gapw) THEN
215 : CALL qs_rho_update_rho(work_matrices%rho_orb_struct_sub, qs_env, &
216 : local_rho_set=work_matrices%local_rho_set, &
217 : pw_env_external=sub_env%pw_env, &
218 : task_list_external=sub_env%task_list_orb_soft, &
219 2244 : para_env_external=sub_env%para_env)
220 : CALL prepare_gapw_den(qs_env, work_matrices%local_rho_set, &
221 2244 : do_rho0=(.NOT. is_rks_triplets), pw_env_sub=sub_env%pw_env)
222 7128 : ELSE IF (gapw_xc) THEN
223 : CALL qs_rho_update_rho(work_matrices%rho_orb_struct_sub, qs_env, &
224 : rho_xc_external=work_matrices%rho_xc_struct_sub, &
225 : local_rho_set=work_matrices%local_rho_set, &
226 : pw_env_external=sub_env%pw_env, &
227 : task_list_external=sub_env%task_list_orb, &
228 : task_list_external_soft=sub_env%task_list_orb_soft, &
229 442 : para_env_external=sub_env%para_env)
230 : CALL prepare_gapw_den(qs_env, work_matrices%local_rho_set, do_rho0=.FALSE., &
231 442 : pw_env_sub=sub_env%pw_env)
232 : ELSE
233 : CALL qs_rho_update_rho(work_matrices%rho_orb_struct_sub, qs_env, &
234 : pw_env_external=sub_env%pw_env, &
235 : task_list_external=sub_env%task_list_orb, &
236 6686 : para_env_external=sub_env%para_env)
237 : END IF
238 : END IF
239 :
240 20972 : DO ispin = 1, nspins
241 20972 : CALL dbcsr_set(work_matrices%A_ia_munu_sub(ispin)%matrix, 0.0_dp)
242 : END DO
243 :
244 : ! electron-hole exchange-correlation interaction
245 20972 : DO ispin = 1, nspins
246 20972 : CALL pw_zero(work_matrices%A_ia_rspace_sub(ispin))
247 : END DO
248 :
249 : ! Skip kernel if collinear xc-kernel for spin-flip is requested
250 9544 : IF (spinflip /= tddfpt_sf_col) THEN
251 9426 : IF ((.NOT. dft_control%tddfpt2_control%do_bse) .AND. (.NOT. dft_control%tddfpt2_control%do_bse_w_only)) THEN
252 9082 : IF ((.NOT. dft_control%tddfpt2_control%do_bse_gw_only)) THEN
253 : ! C_x d^{2}E_{x}^{DFT}[\rho] / d\rho^2
254 : ! + C_{HF} d^{2}E_{x, ADMM}^{DFT}[\rho] / d\rho^2 in case of ADMM calculation
255 9082 : IF (do_onecenter) THEN
256 2686 : rho_atom_set => sub_env%local_rho_set%rho_atom_set
257 2686 : rho1_atom_set => work_matrices%local_rho_set%rho_atom_set
258 : END IF
259 : !
260 9082 : IF (gapw_xc) THEN
261 442 : IF (kernel_env%do_exck) THEN
262 0 : CPABORT("NYA")
263 : ELSE
264 : CALL qs_fxc_apply(qs_env, kernel_env%xc_deriv_set, kernel_env%xc_rho_set, &
265 : work_matrices%rho_xc_struct_sub, rho_atom_set, &
266 : kernel_env%xc_section, do_onecenter, work_matrices%wpw_rspace_sub, &
267 : fxc_tau, rho1_atom_set, &
268 : do_scale=do_scale, is_triplet=is_rks_triplets, spinflip=do_noncol, &
269 442 : pw_env_ext=sub_env%pw_env, para_env_external=sub_env%para_env)
270 884 : DO ispin = 1, nspins
271 : CALL pw_axpy(work_matrices%wpw_rspace_sub(ispin), &
272 884 : work_matrices%A_ia_rspace_sub(ispin), kernel_env%alpha)
273 : END DO
274 :
275 : END IF
276 884 : DO ispin = 1, nspins
277 : CALL pw_scale(work_matrices%A_ia_rspace_sub(ispin), &
278 442 : work_matrices%A_ia_rspace_sub(ispin)%pw_grid%dvol)
279 : CALL integrate_v_rspace(v_rspace=work_matrices%A_ia_rspace_sub(ispin), &
280 : hmat=work_matrices%A_ia_munu_sub(ispin), &
281 : qs_env=qs_env, calculate_forces=.FALSE., gapw=gapw_xc, &
282 : pw_env_external=sub_env%pw_env, &
283 442 : task_list_external=sub_env%task_list_orb_soft)
284 884 : CALL pw_zero(work_matrices%A_ia_rspace_sub(ispin))
285 : END DO
286 : ELSE
287 8640 : IF (kernel_env%do_exck) THEN
288 : CALL tddfpt_apply_xc_potential(work_matrices%A_ia_rspace_sub, work_matrices%fxc_rspace_sub, &
289 156 : work_matrices%rho_orb_struct_sub, is_rks_triplets)
290 : ELSE
291 : CALL qs_fxc_apply(qs_env, kernel_env%xc_deriv_set, kernel_env%xc_rho_set, &
292 : work_matrices%rho_orb_struct_sub, rho_atom_set, &
293 : kernel_env%xc_section, do_onecenter, work_matrices%wpw_rspace_sub, &
294 : fxc_tau, rho1_atom_set, &
295 : do_scale=do_scale, is_triplet=is_rks_triplets, spinflip=do_noncol, &
296 8484 : pw_env_ext=sub_env%pw_env, para_env_external=sub_env%para_env)
297 18852 : DO ispin = 1, nspins
298 : CALL pw_axpy(work_matrices%wpw_rspace_sub(ispin), &
299 18852 : work_matrices%A_ia_rspace_sub(ispin), kernel_env%alpha)
300 : END DO
301 :
302 : END IF
303 : END IF
304 :
305 : END IF ! do_bse
306 : END IF ! do_bse
307 : END IF ! spin-flip
308 :
309 : ! Complete the meta-GGA response before the ADMM call reuses the XC work grids.
310 : ! compute_tau includes the factor 1/2 in the gradient-product integral.
311 9544 : IF (ASSOCIATED(fxc_tau)) THEN
312 186 : task_list => sub_env%task_list_orb
313 186 : IF (do_onecenter) task_list => sub_env%task_list_orb_soft
314 394 : DO ispin = 1, nspins
315 208 : CALL pw_scale(fxc_tau(ispin), kernel_env%alpha*fxc_tau(ispin)%pw_grid%dvol)
316 : CALL integrate_v_rspace(v_rspace=fxc_tau(ispin), hmat=work_matrices%A_ia_munu_sub(ispin), &
317 : qs_env=qs_env, calculate_forces=.FALSE., compute_tau=.TRUE., gapw=do_onecenter, &
318 208 : pw_env_external=sub_env%pw_env, task_list_external=task_list)
319 394 : CALL auxbas_pw_pool%give_back_pw(fxc_tau(ispin))
320 : END DO
321 186 : DEALLOCATE (fxc_tau)
322 : END IF
323 :
324 : ! ADMM correction
325 : IF ((.NOT. dft_control%tddfpt2_control%do_bse) .AND. (.NOT. dft_control%tddfpt2_control%do_bse_w_only) &
326 9544 : .AND. (.NOT. dft_control%tddfpt2_control%do_bse_gw_only)) THEN
327 9200 : IF (do_admm .AND. admm_xc_correction) THEN
328 1330 : IF (dft_control%admm_control%aux_exch_func /= do_admm_aux_exch_func_none) THEN
329 : CALL tddfpt_construct_aux_fit_density(rho_orb_struct=work_matrices%rho_orb_struct_sub, &
330 : rho_aux_fit_struct=work_matrices%rho_aux_fit_struct_sub, &
331 : local_rho_set=work_matrices%local_rho_set_admm, &
332 : qs_env=qs_env, sub_env=sub_env, &
333 : wfm_rho_orb=work_matrices%rho_ao_orb_fm_sub, &
334 : wfm_rho_aux_fit=work_matrices%rho_ao_aux_fit_fm_sub, &
335 860 : wfm_aux_orb=work_matrices%wfm_aux_orb_sub)
336 : ! - C_{HF} d^{2}E_{x, ADMM}^{DFT}[\hat{\rho}] / d\hat{\rho}^2
337 860 : IF (admm_symm) THEN
338 860 : CALL dbcsr_get_info(rho_ia_ao_aux_fit(1)%matrix, row_blk_size=blk_sizes)
339 3440 : ALLOCATE (A_xc_munu_sub(nspins))
340 1720 : DO ispin = 1, nspins
341 860 : ALLOCATE (A_xc_munu_sub(ispin)%matrix)
342 : CALL dbcsr_create(matrix=A_xc_munu_sub(ispin)%matrix, name="ADMM_XC", &
343 : dist=sub_env%dbcsr_dist, matrix_type=dbcsr_type_symmetric, &
344 860 : row_blk_size=blk_sizes, col_blk_size=blk_sizes)
345 860 : CALL cp_dbcsr_alloc_block_from_nbl(A_xc_munu_sub(ispin)%matrix, sub_env%sab_aux_fit)
346 1720 : CALL dbcsr_set(A_xc_munu_sub(ispin)%matrix, 0.0_dp)
347 : END DO
348 :
349 860 : IF (admm_env%do_gapw) THEN
350 190 : basis_type = "AUX_FIT_SOFT"
351 190 : task_list => sub_env%task_list_aux_fit_soft
352 : ELSE
353 670 : basis_type = "AUX_FIT"
354 670 : task_list => sub_env%task_list_aux_fit
355 : END IF
356 :
357 860 : IF (admm_env%do_gapw) THEN
358 190 : rho_atom_set => sub_env%local_rho_set_admm%rho_atom_set
359 190 : rho1_atom_set => work_matrices%local_rho_set_admm%rho_atom_set
360 : END IF
361 : CALL qs_fxc_apply(qs_env, kernel_env_admm_aux%xc_deriv_set, kernel_env_admm_aux%xc_rho_set, &
362 : work_matrices%rho_aux_fit_struct_sub, rho_atom_set, &
363 : kernel_env_admm_aux%xc_section, admm_env%do_gapw, &
364 : work_matrices%wpw_rspace_sub, fxc_tau, rho1_atom_set, &
365 : do_scale=do_scale, is_triplet=is_rks_triplets, spinflip=do_noncol, &
366 : pw_env_ext=sub_env%pw_env, kind_set_external=admm_env%admm_gapw_env%admm_kind_set, &
367 860 : para_env_external=sub_env%para_env)
368 1720 : DO ispin = 1, nspins
369 : CALL pw_scale(work_matrices%wpw_rspace_sub(ispin), &
370 860 : kernel_env_admm_aux%alpha*work_matrices%wpw_rspace_sub(ispin)%pw_grid%dvol)
371 : CALL integrate_v_rspace(v_rspace=work_matrices%wpw_rspace_sub(ispin), &
372 : hmat=A_xc_munu_sub(ispin), &
373 : qs_env=qs_env, calculate_forces=.FALSE., &
374 : pw_env_external=sub_env%pw_env, &
375 : basis_type=basis_type, &
376 1720 : task_list_external=task_list)
377 : END DO
378 860 : IF (admm_env%do_gapw) THEN
379 : CALL update_ks_atom(qs_env, A_xc_munu_sub, rho_ia_ao_aux_fit, forces=.FALSE., tddft=.TRUE., &
380 : rho_atom_external=rho1_atom_set, &
381 : kind_set_external=admm_env%admm_gapw_env%admm_kind_set, &
382 : oce_external=admm_env%admm_gapw_env%oce, &
383 190 : sab_external=sub_env%sab_aux_fit)
384 : END IF
385 860 : ALLOCATE (dbwork)
386 860 : CALL dbcsr_create(dbwork, template=work_matrices%A_ia_munu_sub(1)%matrix)
387 : CALL cp_fm_create(work_aux_orb, &
388 860 : matrix_struct=work_matrices%wfm_aux_orb_sub%matrix_struct)
389 : CALL cp_fm_create(work_orb_orb, &
390 860 : matrix_struct=work_matrices%rho_ao_orb_fm_sub%matrix_struct)
391 860 : CALL cp_fm_get_info(work_aux_orb, nrow_global=nao_aux, ncol_global=nao)
392 1720 : DO ispin = 1, nspins
393 : CALL cp_dbcsr_sm_fm_multiply(A_xc_munu_sub(ispin)%matrix, sub_env%admm_A, &
394 860 : work_aux_orb, nao)
395 : CALL parallel_gemm('T', 'N', nao, nao, nao_aux, 1.0_dp, sub_env%admm_A, &
396 860 : work_aux_orb, 0.0_dp, work_orb_orb)
397 860 : CALL dbcsr_copy(dbwork, work_matrices%A_ia_munu_sub(1)%matrix)
398 860 : CALL dbcsr_set(dbwork, 0.0_dp)
399 860 : CALL copy_fm_to_dbcsr(work_orb_orb, dbwork, keep_sparsity=.TRUE.)
400 1720 : CALL dbcsr_add(work_matrices%A_ia_munu_sub(ispin)%matrix, dbwork, 1.0_dp, 1.0_dp)
401 : END DO
402 860 : CALL dbcsr_release(dbwork)
403 860 : DEALLOCATE (dbwork)
404 860 : CALL cp_fm_release(work_aux_orb)
405 860 : CALL cp_fm_release(work_orb_orb)
406 1720 : DO ispin = 1, nspins
407 1720 : CALL dbcsr_deallocate_matrix(A_xc_munu_sub(ispin)%matrix)
408 : END DO
409 1720 : DEALLOCATE (A_xc_munu_sub)
410 : ELSE
411 0 : IF (admm_env%do_gapw) THEN
412 0 : CPWARN("GAPW/ADMM needs symmetric ADMM kernel")
413 0 : CPABORT("GAPW/ADMM@TDDFT")
414 : END IF
415 : CALL qs_fxc_apply(qs_env, kernel_env_admm_aux%xc_deriv_set, kernel_env_admm_aux%xc_rho_set, &
416 : work_matrices%rho_aux_fit_struct_sub, rho_atom_set, &
417 : kernel_env_admm_aux%xc_section, admm_env%do_gapw, &
418 : work_matrices%wpw_rspace_sub, fxc_tau, rho1_atom_set, &
419 : do_scale=do_scale, is_triplet=is_rks_triplets, spinflip=do_noncol, &
420 0 : pw_env_ext=sub_env%pw_env)
421 :
422 0 : DO ispin = 1, nspins
423 : CALL pw_axpy(work_matrices%wpw_rspace_sub(ispin), &
424 0 : work_matrices%A_ia_rspace_sub(ispin), kernel_env_admm_aux%alpha)
425 : END DO
426 :
427 : END IF
428 : END IF
429 : END IF
430 : END IF
431 :
432 : ! electron-hole Coulomb interaction
433 13888 : IF (.NOT. dft_control%tddfpt2_control%do_bse_w_only) THEN
434 9392 : IF (.NOT. dft_control%tddfpt2_control%do_bse_gw_only) THEN
435 9392 : IF ((.NOT. is_rks_triplets) .AND. (spinflip == no_sf_tddfpt)) THEN
436 : ! a sum J_i{alpha}a{alpha}_munu + J_i{beta}a{beta}_munu can be computed by solving
437 : ! the Poisson equation for combined density (rho_{ia,alpha} + rho_{ia,beta}) .
438 : ! The following action will destroy reciprocal-space grid in spin-unrestricted case.
439 10016 : DO ispin = 2, nspins
440 10016 : CALL pw_axpy(rho_ia_g(ispin), rho_ia_g(1))
441 : END DO
442 : CALL tddfpt_apply_coulomb(A_ia_rspace=work_matrices%A_ia_rspace_sub, &
443 : rho_ia_g=rho_ia_g(1), &
444 : local_rho_set=work_matrices%local_rho_set, &
445 : hartree_local=work_matrices%hartree_local, &
446 : qs_env=qs_env, sub_env=sub_env, gapw=gapw, &
447 : work_v_gspace=work_matrices%wpw_gspace_sub(1), &
448 : work_v_rspace=work_matrices%wpw_rspace_sub(1), &
449 8132 : tddfpt_mgrid=tddfpt_mgrid)
450 : END IF
451 :
452 : ! convert from the plane-wave representation into the Gaussian basis set representation
453 20668 : DO ispin = 1, nspins
454 20668 : IF (.NOT. do_lrigpw) THEN
455 : CALL pw_scale(work_matrices%A_ia_rspace_sub(ispin), &
456 11104 : work_matrices%A_ia_rspace_sub(ispin)%pw_grid%dvol)
457 :
458 11104 : IF (gapw) THEN
459 : CALL integrate_v_rspace(v_rspace=work_matrices%A_ia_rspace_sub(ispin), &
460 : hmat=work_matrices%A_ia_munu_sub(ispin), &
461 : qs_env=qs_env, calculate_forces=.FALSE., gapw=gapw, &
462 : pw_env_external=sub_env%pw_env, &
463 2364 : task_list_external=sub_env%task_list_orb_soft)
464 8740 : ELSE IF (gapw_xc) THEN
465 442 : IF (.NOT. is_rks_triplets) THEN
466 : CALL integrate_v_rspace(v_rspace=work_matrices%A_ia_rspace_sub(ispin), &
467 : hmat=work_matrices%A_ia_munu_sub(ispin), &
468 : qs_env=qs_env, calculate_forces=.FALSE., gapw=.FALSE., &
469 442 : pw_env_external=sub_env%pw_env, task_list_external=sub_env%task_list_orb)
470 : END IF
471 : ELSE
472 : CALL integrate_v_rspace(v_rspace=work_matrices%A_ia_rspace_sub(ispin), &
473 : hmat=work_matrices%A_ia_munu_sub(ispin), &
474 : qs_env=qs_env, calculate_forces=.FALSE., gapw=.FALSE., &
475 8298 : pw_env_external=sub_env%pw_env, task_list_external=sub_env%task_list_orb)
476 : END IF
477 : ELSE ! for full kernel using lri
478 : CALL pw_scale(work_matrices%A_ia_rspace_sub(ispin), &
479 172 : work_matrices%A_ia_rspace_sub(ispin)%pw_grid%dvol)
480 172 : lri_v_int => kernel_env%lri_density%lri_coefs(ispin)%lri_kinds
481 172 : CALL get_qs_env(qs_env, nkind=nkind, para_env=para_env)
482 516 : DO ikind = 1, nkind
483 102304 : lri_v_int(ikind)%v_int = 0.0_dp
484 : END DO
485 : CALL integrate_v_rspace_one_center(work_matrices%A_ia_rspace_sub(ispin), &
486 172 : qs_env, lri_v_int, .FALSE., "P_LRI_AUX")
487 516 : DO ikind = 1, nkind
488 204092 : CALL para_env%sum(lri_v_int(ikind)%v_int)
489 : END DO
490 : END IF ! for full kernel using lri
491 : END DO
492 :
493 : ! local atom contributions
494 9392 : IF (.NOT. do_lrigpw) THEN
495 9220 : IF (gapw .OR. gapw_xc) THEN
496 : ! rho_ia_ao will not be touched
497 : CALL update_ks_atom(qs_env, work_matrices%A_ia_munu_sub, rho_ia_ao, forces=.FALSE., &
498 : rho_atom_external=work_matrices%local_rho_set%rho_atom_set, &
499 2686 : tddft=.TRUE.)
500 : END IF
501 : END IF
502 :
503 : ! calculate Coulomb contribution to response vector for lrigpw !
504 : ! this is restricting lri to Coulomb only at the moment !
505 9392 : IF (do_lrigpw .AND. (.NOT. is_rks_triplets)) THEN !
506 172 : CALL tddfpt2_lri_Amat(qs_env, sub_env, kernel_env%lri_env, lri_v_int, work_matrices%A_ia_munu_sub)
507 : END IF
508 :
509 20668 : DO ispin = 1, nspins
510 20668 : IF (ALLOCATED(work_matrices%evects_sub)) THEN
511 : CALL cp_dbcsr_sm_fm_multiply(work_matrices%A_ia_munu_sub(ispin)%matrix, &
512 : sub_env%mos_active(ispin), &
513 : work_matrices%Aop_evects_sub(ispin, ivect), &
514 8 : ncol=nactive(ispin), alpha=1.0_dp, beta=0.0_dp)
515 : ELSE
516 : CALL cp_dbcsr_sm_fm_multiply(work_matrices%A_ia_munu_sub(ispin)%matrix, &
517 : sub_env%mos_active(ispin), &
518 : Aop_evects(ispin, ivect), &
519 11268 : ncol=nactive(ispin), alpha=1.0_dp, beta=0.0_dp)
520 : END IF
521 : END DO
522 : END IF
523 : END IF
524 : END DO
525 :
526 4344 : CALL timestop(handle)
527 :
528 4344 : END SUBROUTINE fhxc_kernel
529 :
530 : ! **************************************************************************************************
531 : !> \brief Compute action matrix-vector products with the sTDA Kernel
532 : !> \param Aop_evects action of TDDFPT operator on trial vectors (modified on exit)
533 : !> \param evects TDDFPT trial vectors
534 : !> \param is_rks_triplets indicates that a triplet excited states calculation using
535 : !> spin-unpolarised molecular orbitals has been requested
536 : !> \param qs_env Quickstep environment
537 : !> \param stda_control control parameters for sTDA kernel
538 : !> \param stda_env ...
539 : !> \param sub_env parallel (sub)group environment
540 : !> \param work_matrices collection of work matrices (modified on exit)
541 : !> \par History
542 : !> * 04.2019 initial version [JHU]
543 : ! **************************************************************************************************
544 2416 : SUBROUTINE stda_kernel(Aop_evects, evects, is_rks_triplets, &
545 : qs_env, stda_control, stda_env, &
546 : sub_env, work_matrices)
547 :
548 : TYPE(cp_fm_type), DIMENSION(:, :), INTENT(INOUT) :: Aop_evects
549 : TYPE(cp_fm_type), DIMENSION(:, :), INTENT(IN) :: evects
550 : LOGICAL, INTENT(in) :: is_rks_triplets
551 : TYPE(qs_environment_type), POINTER :: qs_env
552 : TYPE(stda_control_type) :: stda_control
553 : TYPE(stda_env_type) :: stda_env
554 : TYPE(tddfpt_subgroup_env_type) :: sub_env
555 : TYPE(tddfpt_work_matrices), INTENT(inout) :: work_matrices
556 :
557 : CHARACTER(LEN=*), PARAMETER :: routineN = 'stda_kernel'
558 :
559 : INTEGER :: handle, ivect, nvects
560 :
561 2416 : CALL timeset(routineN, handle)
562 :
563 2416 : nvects = SIZE(evects, 2)
564 :
565 9762 : DO ivect = 1, nvects
566 9762 : IF (ALLOCATED(work_matrices%evects_sub)) THEN
567 0 : IF (ASSOCIATED(work_matrices%evects_sub(1, ivect)%matrix_struct)) THEN
568 : CALL stda_calculate_kernel(qs_env, stda_control, stda_env, sub_env, work_matrices, &
569 : is_rks_triplets, work_matrices%evects_sub(:, ivect), &
570 0 : work_matrices%Aop_evects_sub(:, ivect))
571 : ELSE
572 : ! skip trial vectors which are assigned to different parallel groups
573 : CYCLE
574 : END IF
575 : ELSE
576 : CALL stda_calculate_kernel(qs_env, stda_control, stda_env, sub_env, work_matrices, &
577 7346 : is_rks_triplets, evects(:, ivect), Aop_evects(:, ivect))
578 : END IF
579 : END DO
580 :
581 2416 : CALL timestop(handle)
582 :
583 2416 : END SUBROUTINE stda_kernel
584 :
585 : ! **************************************************************************************************
586 :
587 : END MODULE qs_tddfpt2_fhxc
|
